## The Einstein Puzzle

There are five houses of different colors next to each other on the same road. In each house lives a man of a different nationality. Every man has his favorite drink, his favorite brand of cigarettes, and keeps pets of a particular kind.

1. The Englishman lives in the red house.
2. The Swede keeps dogs.
3. The Dane drinks tea.
4. The green house is just to the left of the white one.
5. The owner of the green house drinks coffee.
6. The Pall Mall smoker keeps birds.
7. The owner of the yellow house smokes Dunhills.
8. The man in the center house drinks milk.
9. The Norwegian lives in the first house.
10. The Blend smoker has a neighbor who keeps cats.
11. The man who smokes Blue Masters drinks beer.
12. The man who keeps horses lives next to the Dunhill smoker.
13. The German smokes Prince.
14. The Norwegian lives next to the blue house.
15. The Blend smoker has a neighbor who drinks water.

**Who keeps fish?**

I expressed these constraints in the Alloy language and then ran the Alloy Analyzer to find an instance. One instance was found:



You can see that it satisfies all the constraints.

The answer to the question is: The German keeps fish (house #4).

Let’s model this “system.” First, there are a set of houses. Each house has a color. The resident has a nationality, a favorite drink, a favorite cigarette, and a pet. Here’s how to express the set of houses:

**sig** House {
 color: Color,
 nationality: Nationality,
 drink: Drink,
 cigarette: Cigarette,
 pet: Pet
}

The houses are ordered – there is a first house, a second house, a last house. Call the ordering module with the set of houses:

**open** util/ordering[House]

Each house has a different color:

**abstract** **sig** Color {}
**one** **sig** red **extends** Color {}
**one** **sig** green **extends** Color {}
**one** **sig** yellow **extends** Color {}
**one** **sig** blue **extends** Color {}
**one** **sig** white **extends** Color {}

Each resident has a different nationality:

**abstract** **sig** Nationality {}
**one** **sig** Englishman **extends** Nationality {}
**one** **sig** Swede **extends** Nationality {}
**one** **sig** Dane **extends** Nationality {}
**one** **sig** German **extends** Nationality {}
**one** **sig** Norwegian **extends** Nationality {}

Each resident has a different favorite drink:

**abstract** **sig** Drink {}
**one** **sig** tea **extends** Drink {}
**one** **sig** coffee **extends** Drink {}
**one** **sig** milk **extends** Drink {}
**one** **sig** beer **extends** Drink {}
**one** **sig** water **extends** Drink {}

Each resident has a different brand of cigarettes:

**abstract** **sig** Cigarette {}
**one** **sig** Pall\_Mall **extends** Cigarette {}
**one** **sig** Dunhills **extends** Cigarette {}
**one** **sig** Blend **extends** Cigarette {}
**one** **sig** Blue\_Masters **extends** Cigarette {}
**one** **sig** Prince **extends** Cigarette {}

Each resident has a different pet:

**abstract** sig Pet {}
**one** **sig** dog **extends** Pet {}
**one** **sig** bird **extends** Pet {}
**one** **sig** horse **extends** Pet {}
**one** **sig** cat **extends** Pet {}
**one** **sig** fish **extends** Pet {}

There are five houses, each of a different color.

**some** **disj** h1, h2, h3, h4, h5: House | h1.color = red **and**
 h2.color = green **and**
 h3.color = yellow **and**
 h4.color = blue **and**
 h5.color = white

The keyword **disj** (disjoint) means that h1, h2, …, h5 are five different houses. So, there are 5 different houses, with one house having the color red, another with color, green, etc. Note: it does *not* say that the first house has color red, the second house has color green, etc. It just says that *some* house has color red, some house has color green, etc.

The resident in each house is of a different nationality. Stated another way, there are no occurrences of two different houses h and h’, where the nationality of the resident in h is the same as the nationality of the resident in h’.

**no** **disj** h,h': House | h.nationality = h'.nationality

1. The Englishman lives in the red house. That is, there is some house h such that the nationality of h’s resident is Englishman and the color of h is red.

**some** h: House | (h.nationality = Englishman) **and** (h.color = red)

2. The Swede keeps dogs.

**some** h: House | (h.nationality = Swede) **and** (h.pet = dog)

3. The Dane drinks tea.

**some** h: House | (h.nationality = Dane) **and** (h.drink = tea)

4. The green house is just to the left of the white one. That is, there are two houses h and h’ such that h is green, h’ is white, and h occurs before h’ (recall the houses are ordered).

**some** **disj** h, h': House | (h.color = green) **and** (h'.color = white) **and** (h'.prev = h)

5. The owner of the green house drinks coffee.

**some** h: House | (h.color = green) **and** (h.drink = coffee)

6. The Pall Mall smoker keeps birds.

**some** h: House | (h.cigarette = Pall\_Mall) **and** (h.pet = bird)

7. The owner of the yellow house smokes Dunhills.

**some** h: House | (h.color = yellow) **and** (h.cigarette = Dunhills)

8. The man in the center house drinks milk. For the house to be in the “center” there must be some house two houses to the left and two houses to the right, i.e., prev.prev and next.next

**some** h: House | (**some** h.prev.prev) **and** (**some** h.next.next) **and** (h.drink = milk)

9. The Norwegian lives in the first house.

**some** h: House | (h = first) **and** (h.nationality = Norwegian)

10. The Blend smoker has a neighbor who keeps cats. There are two houses h and h’ such that the brand of cigarette preferred by the resident in h is Blend, and the resident in h’ has a cat and h’ is either one house to the left of one house to the right.

**some** **disj** h,h': House | (h.cigarette = Blend) **and** (h'.pet = cat) **and** ((h.prev = h') **or** (h.next = h'))

11. The man who smokes Blue Masters drinks beer.

**some** h: House | (h.cigarette = Blue\_Masters) **and** (h.drink = beer)

12. The man who keeps horses lives next to the Dunhill smoker.

**some** **disj** h,h': House | (h.pet = horse) **and** (h'.cigarette = Dunhills) **and** ((h.next = h') **or** (h.prev = h'))

13. The German smokes Prince.

**some** h: House | (h.nationality = German) **and** (h.cigarette = Prince)

14. The Norwegian lives next to the blue house. From constraint #9 we know that the Norwegian lives in the first house. So, the blue house must be to the right of the Norwegian house.

**some** **disj** h,h': House | (h.nationality = Norwegian) **and** (h'.color= blue) **and** (h.next = h')

15. The Blend smoker has a neighbor who drinks water.

**some** **disj** h,h': House | (h.cigarette = Blend) **and** (h'.drink = water) **and** ((h.next = h') **or** (h.prev = h'))

The complete Alloy model is shown below.

## The complete Alloy model

**open** util/ordering[House]

**sig** House {
 color: Color,
 nationality: Nationality,
 drink: Drink,
 cigarette: Cigarette,
 pet: Pet
}

**abstract** **sig** Color {}
**one** **sig** red **extends** Color {}
**one** **sig** green **extends** Color {}
**one** **sig** yellow **extends** Color {}
**one** **sig** blue **extends** Color {}
**one** **sig** white **extends** Color {}

**abstract** **sig** Nationality {}
**one** **sig** Englishman **extends** Nationality {}
**one** **sig** Swede **extends** Nationality {}
**one** **sig** Dane **extends** Nationality {}
**one** **sig** German **extends** Nationality {}
**one** **sig** Norwegian **extends** Nationality {}

**abstract** **sig** Drink {}
**one** **sig** tea **extends** Drink {}
**one** **sig** coffee **extends** Drink {}
**one** **sig** milk **extends** Drink {}
**one** **sig** beer **extends** Drink {}
**one** **sig** water **extends** Drink {}

**abstract** **sig** Cigarette {}
**one** **sig** Pall\_Mall **extends** Cigarette {}
**one** **sig** Dunhills **extends** Cigarette {}
**one** **sig** Blend **extends** Cigarette {}
**one** **sig** Blue\_Masters **extends** Cigarette {}
**one** **sig** Prince **extends** Cigarette {}

**abstract** sig Pet {}
**one** **sig** dog **extends** Pet {}
**one** **sig** bird **extends** Pet {}
**one** **sig** horse **extends** Pet {}
**one** **sig** cat **extends** Pet {}
**one** **sig** fish **extends** Pet {}

**fact** constraints {
 // There are five houses, each of a different color.
 **some** **disj** h1, h2, h3, h4, h5: House | h1.color = red **and** h2.color = green **and** h3.color = yellow **and**
 h4.color = blue **and** h5.color = white

 // In each house lives a man of a different nationality.
 **no** **disj** h,h': House | h.nationality = h'.nationality

 // 1. The Englishman lives in the red house.
 **some** h: House | (h.nationality = Englishman) **and** (h.color = red)

 // 2. The Swede keeps dogs.
 **some** h: House | (h.nationality = Swede) **and** (h.pet = dog)

 // 3. The Dane drinks tea.
 **some** h: House | (h.nationality = Dane) **and** (h.drink = tea)

 // 4. The green house is just to the left of the white one.
 **some** **disj** h, h': House | (h.color = green) **and** (h'.color = white) **and** (h'.prev = h)

 // 5. The owner of the green house drinks coffee.
 **some** h: House | (h.color = green) **and** (h.drink = coffee)

 // 6. The Pall Mall smoker keeps birds.
 **some** h: House | (h.cigarette = Pall\_Mall) **and** (h.pet = bird)

 // 7. The owner of the yellow house smokes Dunhills.
 **some** h: House | (h.color = yellow) **and** (h.cigarette = Dunhills)

 // 8. The man in the center house drinks milk.
 **some** h: House | (some h.prev.prev) **and** (some h.next.next) **and** (h.drink = milk)

 // 9. The Norwegian lives in the first house.
 **some** h: House | (h = first) **and** (h.nationality = Norwegian)

 // 10. The Blend smoker has a neighbor who keeps cats.
 **some** **disj** h,h': House | (h.cigarette = Blend) **and** (h'.pet = cat) **and** ((h.prev = h') **or** (h.next = h'))

 // 11. The man who smokes Blue Masters drinks beer.
 **some** h: House | (h.cigarette = Blue\_Masters) **and** (h.drink = beer)

 // 12. The man who keeps horses lives next to the Dunhill smoker.
 **some** **disj** h,h': House | (h.pet = horse) **and** (h'.cigarette = Dunhills) **and** ((h.next = h') **or** (h.prev = h'))

 // 13. The German smokes Prince.
 **some** h: House | (h.nationality = German) **and** (h.cigarette = Prince)

 // 14. The Norwegian lives next to the blue house.
 **some** **disj** h,h': House | (h.nationality = Norwegian) **and** (h'.color= blue) **and** (h.next = h')

 // 15. The Blend smoker has a neighbor who drinks water.
 **some** **disj** h,h': House | (h.cigarette = Blend) **and** (h'.drink = water) **and** ((h.next = h') **or** (h.prev = h'))

}

**run** {} **for** 5